我的看盘面板（一个集个股形态位置财务状况于一体的看盘面板）

一、说明：

1、我使用的看盘软件是通达信（windows平台免费版V7.622）。

2、本界面重点看振荡走势中当前的价格在相对时间段内所处的位置，主要由二部分构成，主图看相对位置，副图了解个股的基本情况及动量情况，能达到在一个界面下比较全部地了解个股的位置形态及基本信息。

二、 编制方法

（一）主图技术指标编制与使用

步骤1：在公式管理器中新建一个公式名称为“我的面板1”画线方法选“主图叠加”，设置二个参数，M[1-1000-200]N[1-20-1]。

步骤2：将下面的代码无脑拷贝到代码编辑区。

平台周期:M,NODRAW;

上轨:CONST(REF(HHV(HIGH,M),N)),COLORLIMAGENTA,DOTLINE;

下轨:CONST(LLV(LOW,M)),COLORLIMAGENTA,DOTLINE;

空间:上轨-下轨,NODRAW;

平台最大振幅%:(上轨-下轨)/下轨*100,NODRAW;

高点值:=CONST(HHV(HIGH,M));

高点位置:=CONST(HHVBARS(HIGH,M));

低点值:=CONST(LLV(LOW,M));

低点位置:=CONST(LLVBARS(L,M));

相对上轨调整:=(上轨-DYNAINFO(7))/上轨*100,NODRAW;

相对下轨上涨:=(DYNAINFO(7)-下轨)/下轨*100,NODRAW;

相对调整:=STRCAT(STRCAT("相对上轨调整: ",CON2STR((高点值-DYNAINFO(7))/高点值*100,2)),"%");

相对上涨:=STRCAT(STRCAT("相对下轨上涨: ",CON2STR((DYNAINFO(7)-低点值)/低点值*100,2)),"%");

调0191值:=STRCAT("相对上轨调整0191价: ",CON2STR((高点值-高点值*0.192),2));

调0382值:=STRCAT("相对上轨调整0382价: ",CON2STR((高点值-高点值*0.382),2));

调05值:=STRCAT("相对上轨调整 05价: ",CON2STR((高点值-高点值*0.5),2));

调0618值:=STRCAT("相对上轨调整0618价: ",CON2STR((高点值-高点值*0.618),2));

调30%值:=STRCAT("相对上轨调整 30%价: ",CON2STR((高点值-高点值*0.3),2));

DRAWTEXT_FIX(ISLASTBAR,0.005,0.05,0,相对调整),COLORBROWN;

DRAWTEXT_FIX(ISLASTBAR,0.005,0.11,0,相对上涨),COLORBROWN;

DRAWTEXT_FIX(ISLASTBAR,0.005,0.17,0,调0191值),COLORWHITE;

DRAWTEXT_FIX(ISLASTBAR,0.005,0.23,0,调0382值),COLORWHITE;

DRAWTEXT_FIX(ISLASTBAR,0.005,0.29,0,调05值),COLORWHITE;

DRAWTEXT_FIX(ISLASTBAR,0.005,0.35,0,调0618值),COLORWHITE;

DRAWTEXT_FIX(ISLASTBAR,0.005,0.41,0,调30%值),COLORYELLOW;

空间调幅30%:高点值-空间*0.3,COLORGREEN,COLORYELLOW,CROSSDOT;

空间调幅50%:高点值-空间*0.5,COLORGREEN,DOTLINE;

DRAWNUMBER(ISLASTBAR,空间调幅30%,空间调幅30%),COLORYELLOW,;

DRAWNUMBER(ISLASTBAR,空间调幅50%,空间调幅50%),COLORGREEN;

步骤3：在主图上选择公式名为“我的面板1”

使用效果如下图:

顶部提示图

位置形态图

公式说明:

参数M为平台振荡的周期数，默认为200,N为平台距今天的周期数,调整参数M，可看更长或稍短一些的平台，调整参数N，可观察一些突破N天后股价的走势，如果利用平台突破选股公式，找出在相对的平台上且最大振幅在某一指定范围内的所有股票，观察其效果更好。

（二）副图技术指标编制与使用

步骤1：在公式管理器中新建一个公式名称为“个股基情”画线方法选“副图”

步骤2：将下面代码拷贝到公式编辑器的代码区

DRAWRECTREL(0,0,990,990,RGB(20,18,12));

DRAWTEXT_FIX(1,0.50,0.01,1,"基 本 情 况"),COLORRED;

{第一行}

DRAWTEXT_FIX(1,0.01,0.1,0,"行业：")COLORYELLOW;

DRAWTEXT_FIX(1,0.05,0.1,0,HYBLOCK)COLORLIRED;

DRAWTEXT_FIX(1,0.12,0.1,0,"概念：")COLORYELLOW;

DRAWTEXT_FIX(1,0.16,0.1,0,GNBLOCK)COLORLIRED;

DRAWTEXT_FIX(1,0.97,0.1,1,"近期解禁：")COLORYELLOW;

DRAWTEXT_FIX(INBLOCK("即将解禁"),0.98,0.1,1,"是"),COLORLIRED;

DRAWTEXT_FIX(NOT(INBLOCK("即将解禁")),0.98,0.1,1,"否"),COLORLIRED;

{第二行}

上市天数:=FINANCE(42);

DRAWTEXT_FIX(ISLASTBAR,0.01,0.22,0,STRCAT("上市天数： ",STRCAT(CON2STR(FINANCE(42),0)," 天 ")))COLORYELLOW;

流通盘:=CAPITAL/1000000;

DRAWTEXT_FIX(ISLASTBAR,0.11,0.23,0,STRCAT("流通盘： ",STRCAT(CON2STR(流通盘,2)," 亿股 ")))COLORLIGREEN;

流通市值:=FINANCE(40)/100000000;

DRAWTEXT_FIX(ISLASTBAR,0.22,0.23,0,STRCAT("流通市值： ",STRCAT(CON2STR(流通市值,2)," 亿元 ")))COLORLIRED;

股东人数:=FINVALUE(242);

{股东人数:=GPJYVALUE(1,1,1);}

前十股东持股数:=FINVALUE(244)/100000000;{单位：亿股}

GDAA:=IF(FINONE(242,0,0)<FINONE(242,0,1) AND FINONE(242,0,1)<FINONE(242,0,2) AND FINONE(242,0,2)<FINONE(242,0,3),"连续三季度减少",IF(FINVALUE(242)>FINONE(242,0,1) AND FINONE(242,0,1)>FINONE(242,0,2) AND FINONE(242,0,2)>FINONE(242,0,3),"连续三季度增加",""));

GDEE:=IF(FINONE(247,0,0)<FINONE(247,0,1) AND FINONE(247,0,1)<FINONE(247,0,2) AND FINONE(247,0,2)<FINONE(247,0,3),"连续三季度减少",IF(FINVALUE(247)>FINONE(247,0,1) AND FINONE(247,0,1)>FINONE(247,0,2) AND FINONE(247,0,2)>FINONE(247,0,3),"连续三季度增加",""));

DRAWTEXT_FIX(ISLASTBAR,0.34,0.23,0,STRCAT("股东人数： ",STRCAT(CON2STR(股东人数,0)," 户")))COLORYELLOW;

DRAWTEXT_FIX(ISLASTBAR AND ((FINVALUE(242)-FINONE(242,0,1))/FINONE(242,0,1))<=0,0.44,0.22,0,STRCAT("本期股东人数较上期增加：",STRCAT(CON2STR((FINVALUE(242)-FINONE(242,0,1))/FINONE(242,0,1)*100,2),STRCAT(" %",GDAA)))),COLORLIRED;

DRAWTEXT_FIX(ISLASTBAR AND ((FINVALUE(242)-FINONE(242,0,1))/FINONE(242,0,1))> 0,0.44,0.22,0,STRCAT("本期股东人数较上期增加：",STRCAT(CON2STR((FINVALUE(242)-FINONE(242,0,1))/FINONE(242,0,1)*100,2),STRCAT(" %",GDAA)))),COLORLIRED;

DRAWTEXT_FIX(ISLASTBAR,0.59,0.23,0,STRCAT("前十股东持股： ",STRCAT(CON2STR(前十股东持股数,1)," 亿股 ")))COLORLIGREEN;

DRAWTEXT_FIX(ISLASTBAR,0.70,0.23,0,STRCAT("机构： ",STRCAT(CON2STR(FINVALUE(246),0),STRCAT(" 家 共持有 ",STRCAT(CON2STR(FINVALUE(247)/100000000,2),"亿股"))))),COLORYELLOW;

DRAWTEXT_FIX(ISLASTBAR,0.84,0.23,0,STRCAT("较上期增加： ",STRCAT(CON2STR((FINONE(247,0,0)-FINONE(247,0,1))/FINONE(247,0,1)*100,2),STRCAT(" % ",GDEE)))),COLORGREEN;

{第三行}

{ROE3:=(FINONE(6,YEAR-1,1231)+FINONE(6,YEAR-2,1231)+FINONE(6,YEAR-3,1231))/3;

DRAWTEXT_FIX(ISLASTBAR,0.1,0.32,0,STRCAT("近三年ROE均值： ",STRCAT(CON2STR(ROE3,2),"%"))),COLORYELLOW;}{可用与实用效果同}

ROE3:=(FINONE(6,19,1231)+FINONE(6,20,1231)+FINONE(6,21,1231))/3;

营收增3:=(FINONE(183,19,1231)+FINONE(183,20,1231)+FINONE(183,21,1231))/3;

周转率3:=(FINONE(175,19,1231)+FINONE(175,20,1231)+FINONE(175,21,1231))/3;{总资产周转率＝营业收入/总资产}

净利润增长率3:=(FINONE(184,19,1231)+FINONE(184,20,1231)+FINONE(184,21,1231))/3;

净资平均增长率3:=(FINONE(185,19,1231)+FINONE(185,20,1231)+FINONE(185,21,1231))/3;

毛利率3:=(FINONE(202,19,1231)+FINONE(202,20,1231)+FINONE(202,21,1231))/3;

负债率3:=(FINONE(210,19,1231)+FINONE(210,20,1231)+FINONE(210,21,1231))/3;

DRAWTEXT_FIX(ISLASTBAR,0.01,0.34,0,"近三年指标(平均)："),COLORCYAN;

DRAWTEXT_FIX(ISLASTBAR,0.09,0.34,0,STRCAT("ROE： ",STRCAT(CON2STR(ROE3,2),"%"))),COLORYELLOW;

DRAWTEXT_FIX(ISLASTBAR,0.27,0.34,0,STRCAT("净利润增长率： ",STRCAT(CON2STR(净利润增长率3,2),"%"))),COLORYELLOW;

DRAWTEXT_FIX(ISLASTBAR,0.38,0.34,0,STRCAT("营收增长率： ",STRCAT(CON2STR(营收增3,2),"%"))),COLORLIRED;

DRAWTEXT_FIX(ISLASTBAR,0.16,0.34,0,STRCAT("净资产增长率： ",STRCAT(CON2STR(净资平均增长率3,2),"%"))),COLORLIRED;

DRAWTEXT_FIX(ISLASTBAR,0.48,0.34,0,STRCAT("毛利率： ",STRCAT(CON2STR(毛利率3,2),"%"))),COLORLIGREEN;

DRAWTEXT_FIX(ISLASTBAR,0.56,0.34,0,STRCAT("总资产周转率： ",STRCAT(CON2STR(周转率3,2),"%"))),COLORLIGREEN;

DRAWTEXT_FIX(ISLASTBAR,0.67,0.34,0,STRCAT("负债率： ",STRCAT(CON2STR(负债率3,2),"%"))),COLORLIGREEN;

DRAWTEXT_FIX(ISLASTBAR,0.74,0.34,0,STRCAT("当期应收：",STRCAT(CON2STR((FINONE(11,0,0)+FINONE(13,0,0))/100000000,1),"亿元%"))),COLORLIRED;{当期应收与其它应收之和}

DRAWTEXT_FIX(ISLASTBAR,0.84,0.34,0,STRCAT("质押比： ",STRCAT(CON2STR(GPJYVALUE(20,1,1),2),"%"))),COLORLIRED;

DRAWTEXT_FIX(ISLASTBAR,0.93,0.34,0,STRCAT("商誉(亿)：",CON2STR(FINVALUE(35)/100000000,2))),COLORLIRED;

{第四行自定义部分}

{涨停K线}

ZB:=0.1;

KCB:=0.2;

CYKC:=CODELIKE("3") OR CODELIKE("688");

CYKC1:=CODELIKE("688");

FD:=IF(CYKC,KCB,ZB);

ZT:=C=ZTPRICE(REF(C,1),FD);

{跌停K线}

DT:=C=DTPRICE(REF(C,1),FD);

{700天内涨跌停统计}

T1:=700;{2年}

涨停价:=ZTPRICE(REF(C,1),FD);

跌停价:=DTPRICE(REF(C,1),FD);

ZTTJ:=C>=涨停价 AND C=H;

DTTJ:=C<=跌停价 AND C=L;

ZTSL:=BARSLASTCOUNT(ZTTJ=1);

涨停数:=COUNT((ZTTJ),T1);

最高连板数:=HHV(ZTSL,T1);

最高连板:=IF(最高连板数>1,最高连板数,0);

跌停数:=COUNT(DTTJ,T1);

开板:=((H>=涨停价) AND (C<涨停价));

开板数:=COUNT(开板,T1);

封板率:=(1-(开板数/(涨停数+开板数)))*100;

连板次数:=COUNT(BARSLASTCOUNT(ZTTJ=1)=2,T1);

DRAWTEXT_FIX(ISLASTBAR,0.01,0.45,0,STRCAT("近二年涨停数： ",CON2STR(涨停数,0))),COLORLIGREEN;

DRAWTEXT_FIX(ISLASTBAR,0.10,0.45,0,STRCAT("跌停数： ",CON2STR(跌停数,0))),COLORLIGREEN;

DRAWTEXT_FIX(ISLASTBAR,0.20,0.45,0,STRCAT("最高连板： ",CON2STR(最高连板,0))),COLORLIGREEN;

DRAWTEXT_FIX(ISLASTBAR,0.30,0.45,0,STRCAT("连板次数： ",CON2STR(连板次数,0))),COLORLIGREEN;

DRAWTEXT_FIX(ISLASTBAR,0.40,0.45,0,STRCAT("开板数： ",CON2STR(开板数,0))),COLORLIGREEN;

DRAWTEXT_FIX(ISLASTBAR,0.50,0.45,0,STRCAT("封板率： ",STRCAT(CON2STR(封板率,2),"%"))),COLORLIGREEN;

DRAWTEXT_FIX(ISLASTBAR,0.60,0.45,0,STRCAT("距今涨停： ",STRCAT(CON2STR(CONST(BARSLAST(ZTTJ)),0),"天"))),COLORLIGREEN;

{第五行}

换手率:=VOL/CAPITAL*100;

完全换手:=SUMBARS(VOL,CAPITAL);

换手100:=SUM(换手率,100);{100天换手累计}

振幅100:=(HHV(H,100)-LLV(L,100))/LLV(L,100)*100;

区涨幅30:=(C-REF(C,30))/REF(C,30)*100;

平均成本:=MCST;{系统自带加密}

RZYE:=REF(GPJYVALUE(3,1,1),1)/10000;{当天未出数据统一用前一天的，单位：亿}

RQYE:=REF(GPJYVALUE(3,2,1),1)/10000;

BZCG:=REF(GPJYVALUE(6,1,1),1)/10000;{陆股通即北向资金持股，单位：万}

DRAWTEXT_FIX(ISLASTBAR,0.01,0.56,0,STRCAT("换手率(100)： ",STRCAT(CON2STR(换手100,0),"%"))),COLORLIGREEN;

DRAWTEXT_FIX(ISLASTBAR,0.10,0.56,0,STRCAT("完全换手前： ",STRCAT(CON2STR(完全换手,0),"天"))),COLORLIGREEN;

DRAWTEXT_FIX(ISLASTBAR,0.20,0.56,0,STRCAT("振幅(100)： ",STRCAT(CON2STR(振幅100,0),"%"))),COLORLIGREEN;

DRAWTEXT_FIX(ISLASTBAR,0.30,0.56,0,STRCAT("区间涨幅(30)： ",STRCAT(CON2STR(区涨幅30,2),"%"))),COLORLIGREEN;

DRAWTEXT_FIX(ISLASTBAR,0.42,0.56,0,STRCAT("平均成本： ",STRCAT(CON2STR(MCST,2),"元"))),COLORCYAN;

DRAWTEXT_FIX(ISLASTBAR,0.53,0.56,0,STRCAT("获利盘占比： ",STRCAT(CON2STR(WINNER(MCST)*100,1),"%"))),COLORCYAN;

DRAWTEXT_FIX(ISLASTBAR,0.65,0.56,0,STRCAT("融资余额： ",STRCAT(CON2STR(RZYE,1),"亿元"))),COLORCYAN;

DRAWTEXT_FIX(ISLASTBAR,0.75,0.56,0,STRCAT("融券余额： ",STRCAT(CON2STR(RQYE,1),"万股"))),COLORCYAN;

DRAWTEXT_FIX(ISLASTBAR,0.87,0.56,0,STRCAT("北资持股： ",STRCAT(CON2STR(BZCG,1),"万股"))),COLORCYAN;

步骤3：调用副图指标，效果图如下

三 、总体功能

在一个界面上实现个股形态及相对位置的直观展示，同时在下面副图中呈现出个股的基本情况。

在此基础上，你可以改写公式，获得更长时间：如近五年公司的ROE、净利润增长率等指标，也可获取公司其它的经营指标。

特别说明：使用指标前，一定要下载最新的盘后数据和专业财务数据。